89 lines
2.1 KiB
Nix
89 lines
2.1 KiB
Nix
|
{ lib
|
||
|
|
, stdenv
|
||
|
|
, fetchFromGitHub
|
||
|
|
, rocmUpdateScript
|
||
|
|
, cmake
|
||
|
|
, rocm-cmake
|
||
|
|
, clr
|
||
|
|
, gtest
|
||
|
|
, gbenchmark
|
||
|
|
, buildTests ? false
|
||
|
|
, buildBenchmarks ? false
|
||
|
|
, gpuTargets ? [ ]
|
||
|
|
}:
|
||
|
|
|
||
|
|
stdenv.mkDerivation (finalAttrs: {
|
||
|
|
pname = "rocrand";
|
||
|
|
version = "5.7.1";
|
||
|
|
|
||
|
|
outputs = [
|
||
|
|
"out"
|
||
|
|
] ++ lib.optionals buildTests [
|
||
|
|
"test"
|
||
|
|
] ++ lib.optionals buildBenchmarks [
|
||
|
|
"benchmark"
|
||
|
|
];
|
||
|
|
|
||
|
|
src = fetchFromGitHub {
|
||
|
|
owner = "ROCm";
|
||
|
|
repo = "rocRAND";
|
||
|
|
rev = "rocm-${finalAttrs.version}";
|
||
|
|
hash = "sha256-VrpiHlZZQH+IOoaEDuDOfRgnMiqm1bpRIuNyrPz2SGY=";
|
||
|
|
fetchSubmodules = true; # For inline hipRAND
|
||
|
|
};
|
||
|
|
|
||
|
|
nativeBuildInputs = [
|
||
|
|
cmake
|
||
|
|
rocm-cmake
|
||
|
|
clr
|
||
|
|
];
|
||
|
|
|
||
|
|
buildInputs = lib.optionals buildTests [
|
||
|
|
gtest
|
||
|
|
] ++ lib.optionals buildBenchmarks [
|
||
|
|
gbenchmark
|
||
|
|
];
|
||
|
|
|
||
|
|
cmakeFlags = [
|
||
|
|
"-DCMAKE_C_COMPILER=hipcc"
|
||
|
|
"-DCMAKE_CXX_COMPILER=hipcc"
|
||
|
|
"-DHIP_ROOT_DIR=${clr}"
|
||
|
|
# Manually define CMAKE_INSTALL_<DIR>
|
||
|
|
# See: https://github.com/NixOS/nixpkgs/pull/197838
|
||
|
|
"-DCMAKE_INSTALL_BINDIR=bin"
|
||
|
|
"-DCMAKE_INSTALL_LIBDIR=lib"
|
||
|
|
"-DCMAKE_INSTALL_INCLUDEDIR=include"
|
||
|
|
] ++ lib.optionals (gpuTargets != [ ]) [
|
||
|
|
"-DAMDGPU_TARGETS=${lib.concatStringsSep ";" gpuTargets}"
|
||
|
|
] ++ lib.optionals buildTests [
|
||
|
|
"-DBUILD_TEST=ON"
|
||
|
|
] ++ lib.optionals buildBenchmarks [
|
||
|
|
"-DBUILD_BENCHMARK=ON"
|
||
|
|
];
|
||
|
|
|
||
|
|
postInstall = lib.optionalString buildTests ''
|
||
|
|
mkdir -p $test/bin
|
||
|
|
mv $out/bin/test_* $test/bin
|
||
|
|
'' + lib.optionalString buildBenchmarks ''
|
||
|
|
mkdir -p $benchmark/bin
|
||
|
|
mv $out/bin/benchmark_* $benchmark/bin
|
||
|
|
'' + lib.optionalString (buildTests || buildBenchmarks) ''
|
||
|
|
rmdir $out/bin
|
||
|
|
'';
|
||
|
|
|
||
|
|
passthru.updateScript = rocmUpdateScript {
|
||
|
|
name = finalAttrs.pname;
|
||
|
|
owner = finalAttrs.src.owner;
|
||
|
|
repo = finalAttrs.src.repo;
|
||
|
|
};
|
||
|
|
|
||
|
|
meta = with lib; {
|
||
|
|
description = "Generate pseudo-random and quasi-random numbers";
|
||
|
|
homepage = "https://github.com/ROCm/rocRAND";
|
||
|
|
license = with licenses; [ mit ];
|
||
|
|
maintainers = teams.rocm.members;
|
||
|
|
platforms = platforms.linux;
|
||
|
|
broken = versions.minor finalAttrs.version != versions.minor stdenv.cc.version || versionAtLeast finalAttrs.version "6.0.0";
|
||
|
|
};
|
||
|
|
})
|