depot/ops/nixos/howl/default.nix

# SPDX-FileCopyrightText: 2020 Luke Granger-Brown <depot@lukegb.com>
#
# SPDX-License-Identifier: Apache-2.0

{ depot, lib, pkgs, config, ... }:
let
  inherit (depot.ops) secrets;
in {
  imports = [
    ../lib/zfs.nix
    ../lib/graphical-client-wayland.nix
    ../lib/whitby-distributed.nix
  ];

  boot.initrd.availableKernelModules = [
    "xhci_pci"
    "ahci"
    "nvme"
    "usbhid"
    "usb_storage"
    "sd_mod"
    "rtsx_pci_sdmmc"
  ];
  boot.kernelModules = [ "kvm-intel" ];
  boot.kernelParams = [ "button.lid_init_state=open" ];
  boot.supportedFilesystems = [ "ntfs" ];
  boot.kernel.sysctl = {
    "abi.vsyscall32" = "0";
  };

  my.ip.tailscale = "100.84.64.91";
  my.rundeck.expectedOnline = false;

  fileSystems = let
    zfs = device: {
      device = device;
      fsType = "zfs";
    };
  in {
    "/" = zfs "zpool/local/root";
    "/nix" = zfs "zpool/local/nix";
    "/tmp" = zfs "zpool/local/tmp";

    "/var" = zfs "zpool/safe/var";
    "/home" = zfs "zpool/safe/home";
    "/persist" = zfs "zpool/safe/persist";

    "/boot" = {
      device = "/dev/disk/by-label/NIXBOOT";
      fsType = "vfat";
    };
  };

  nix.settings.max-jobs = lib.mkDefault 12;
  powerManagement.cpuFreqGovernor = lib.mkDefault "powersave";
  hardware.enableRedistributableFirmware = true;

  # Laptop, don't autodeploy.
  my.deploy.enable = false;

  # Use the systemd-boot EFI boot loader.
  boot.loader.systemd-boot.enable = true;
  boot.loader.efi.canTouchEfiVariables = true;

  # ZFS!
  services.zfs.rollbackOnBoot.enable = true;

  # Enable libvirtd.
  virtualisation.libvirtd.enable = true;
  security.polkit.enable = true;

  networking.hostName = "howl";
  networking.domain = "int.as205479.net";
  networking.hostId = "cdd51451";

  # Boot faster.
  systemd.services.systemd-udev-settle.enable = false;
  systemd.services.NetworkManager-wait-online.enable = false;

  networking.dhcpcd.enable = false;
  networking.networkmanager.enable = true;

  # Set your time zone.
  time.timeZone = "Europe/London";

  # List packages installed in system profile. To search, run:
  # $ nix search wget
  environment.systemPackages = with pkgs; [
    pciutils
    deluge
  ];

  # Enable the X11 windowing system.
  programs.sway = {
    enable = true;
    wrapperFeatures.gtk = true;
  };
  services.xserver.enable = true;
  services.xserver.displayManager.gdm.enable = true;

  hardware.graphics.enable32Bit = true;
  hardware.graphics.extraPackages = with pkgs; [
    intel-media-driver vaapiVdpau libvdpau-va-gl libva
  ];
  hardware.graphics.extraPackages32 = with pkgs.pkgsi686Linux; [ libva ];
  hardware.acpilight.enable = true;

  # Define a user account.
  users.users.lukegb = {
    extraGroups = [ "wheel" "networkmanager" "libvirtd" "video" ];
  };
  my.home-manager.system = {...}: {
    home.packages = lib.mkAfter (with pkgs; [
      steam
      (writeScriptBin "javaws" ''
        #!/bin/sh
        exec ${depot.nix.pkgs.javaws-env}/bin/javaws-env "$@"
      '')
      factorio-experimental
      (depot.nix.pkgs.secretsync.configure {
        workingDir = "/home/lukegb/depot";
        gitlabAccessToken = secrets.deployer.gitlabAccessToken;
        manifestVariable = "SECRETS_MANIFEST";
        variablesToFile = {
          "OPS_SECRETS_DEFAULT_NIX" = "ops/secrets/default.nix";
        };
      })
      efibootmgr
      iw
      obs-studio
      vulkan-tools
    ]);
  };

  # Things to persist.
  services.openssh.hostKeys = [
    {
      path = "/persist/etc/ssh/ssh_host_ed25519_key";
      type = "ed25519";
    }
    {
      path = "/persist/etc/ssh/ssh_host_rsa_key";
      type = "rsa";
      bits = 4096;
    }
  ];
  systemd.tmpfiles.rules = [
    "d /var/lib/libvirt 0755 root - - -"
  ];
  systemd.mounts = let
    bindMount' = dir: {
      unitConfig.RequiresMountsFor = dir;
      options = "bind";
      what = "/persist${dir}";
      where = dir;
    };
    bindMountSvc = dir: svc: (bindMount' dir) // {
      requiredBy = [svc];
    };
    bindMount = dir: (bindMount' dir) // {
      wantedBy = ["multi-user.target"];
    };
  in [
    (bindMountSvc "/var/lib/libvirt" "libvirtd.service")
    (bindMountSvc "/etc/NetworkManager/system-connections" "NetworkManager.service")
    (bindMount "/root")
  ];

  # Enable Thunderbolt device management.
  services.hardware.bolt.enable = true;

  hardware.bluetooth = {
    enable = true;
  };

  nix.buildMachines = [ {
    hostName = "totoro";
    system = "x86_64-linux";
    maxJobs = 4;
    speedFactor = 2;
    supportedFeatures = [ "nixos-test" "benchmark" "big-parallel" "kvm" ];
    mandatoryFeatures = [ ];
  }];

  my.scrapeJournal.enable = false;  # Laptop, don't pull too much.

  services.redis.servers."".enable = true;
  systemd.services.redis.wantedBy = lib.mkForce [];
  services.postgresql.enable = true;
  systemd.services.postgresql.wantedBy = lib.mkForce [];
  services.postgresql.ensureDatabases = [ "lukegb" ];
  services.postgresql.ensureUsers = [{
    name = "lukegb";
  }];
  services.postgresql.authentication = ''
    local all all              trust
    host  all all 127.0.0.1/32 trust
    host  all all ::1/128      trust
  '';

  # This value determines the NixOS release with which your system is to be
  # compatible, in order to avoid breaking some software such as database
  # servers. You should change this only after NixOS release notes say you
  # should.
  system.stateVersion = "23.11"; # Did you read the comment?
}