depot/third_party/lanzaboote.nix

{ pkgs ? import ./nixpkgs { } }:
let
  flakify = f: src: f // { outPath = src; };

  src = pkgs.fetchFromGitHub {
    owner = "nix-community";
    repo = "lanzaboote";
    rev = "2f48272f34174fd2a5ab3df4d8a46919247be879";
    hash = "sha256-zpmAzrvK8KdssBSwiIwwRxaUJ77oWORbW0XFvgCFpTE=";
  };

  flake-parts-src = pkgs.fetchFromGitHub {
    owner = "hercules-ci";
    repo = "flake-parts";
    rev = "506278e768c2a08bec68eb62932193e341f55c90";
    hash = "sha256-hgmguH29K2fvs9szpq2r3pz2/8cJd2LPS+b4tfNFCwE=";
  };
  flake-parts-flake = import "${flake-parts-src}/flake.nix";
  flake-parts = flake-parts-flake.outputs {
    nixpkgs-lib = pkgs;
  };

  rust-overlay-src = pkgs.fetchFromGitHub {
    owner = "oxalica";
    repo = "rust-overlay";
    rev = "8d1b40f8dfd7539aaa3de56e207e22b3cc451825";
    hash = "sha256-Sgax33jGuvVHTjl1P78IwzlhAGyOxtx5Q26inKja8S4=";
  };
  rust-overlay-flake = import "${rust-overlay-src}/flake.nix";
  rust-overlay = rust-overlay-flake.outputs {
    self = rust-overlay;
    nixpkgs = pkgs;
  };

  crane-src = pkgs.fetchFromGitHub {
    owner = "ipetkov";
    repo = "crane";
    rev = "a4ca93905455c07cb7e3aca95d4faf7601cba458";
    hash = "sha256-+XVYfmVXAiYA0FZT7ijHf555dxCe+AoAT5A6RU+6vSo=";
  };
  crane = (import "${crane-src}/flake.nix").outputs {
    nixpkgs = flakify pkgs ./nixpkgs;
    inherit rust-overlay;
  };

  flakeInputs = {
    self = flakeEval;
    nixpkgs = ./nixpkgs;
    crane = crane;
    rust-overlay = rust-overlay;
    inherit flake-parts;
    pre-commit-hooks-nix = null;
  };
  flakeEval = flake.outputs flakeInputs;

  flake = import "${src}/flake.nix";
in
  flakeEval