depot/nix/pkgs/copybara.nix

# SPDX-FileCopyrightText: 2020 Luke Granger-Brown <depot@lukegb.com>
#
# SPDX-License-Identifier: Apache-2.0

{ buildBazelPackage, openjdk11_headless, bazel_4, git, mercurial, makeWrapper, fetchFromGitHub }:
buildBazelPackage rec {
  name = "copybara";
  version = "master";
  bazel = bazel_4;

  src = ../../third_party/copybara;

  nativeBuildInputs = [ git mercurial openjdk11_headless makeWrapper ];

  bazelTarget = "//java/com/google/copybara:copybara_deploy.jar";
  removeRulesCC = false;
  fetchConfigured = true;
  bazelFlags = [
    "--javabase=@local_jdk//:jdk"
    "--host_javabase=@local_jdk//:jdk"
  ];

  fetchAttrs = {
    sha256 = "sha256:1xahy74my2hr9763sv7ch3safj9mp5a78hg163gsnmqhfzvjh2cj";
    preHook = ''
      export COURSIER_CACHE="$(echo ''${NIX_BUILD_TOP}/tmp/coursier | sed -e 's,//,/,g')"
    '';
  };

  buildAttrs = {
    installPhase = ''
      mkdir -p $out/bin $out/share/java
      install -Dm755 bazel-bin/java/com/google/copybara/copybara_deploy.jar $out/share/java/copybara.jar
      makeWrapper ${openjdk11_headless}/bin/java $out/bin/copybara \
        --add-flags "-cp $out/share/java/copybara.jar com.google.copybara.Main"
    '';
  };
}