111 lines
4 KiB
Nix
111 lines
4 KiB
Nix
|
{ stdenv, lib, fetchurl, fetchpatch, texlive, bison, flex, lapack, blas
|
||
|
|
, gmp, mpfr, pari, ntl, gsl, mpfi, ecm, glpk, nauty
|
||
|
|
, readline, gettext, libpng, libao, gfortran, perl
|
||
|
|
, enableGUI ? false, libGL ? null, libGLU ? null, xorg ? null, fltk ? null
|
||
|
|
}:
|
||
|
|
|
||
|
|
assert enableGUI -> libGLU != null && libGL != null && xorg != null && fltk != null;
|
||
|
|
assert (!blas.isILP64) && (!lapack.isILP64);
|
||
|
|
|
||
|
|
stdenv.mkDerivation rec {
|
||
|
|
pname = "giac${lib.optionalString enableGUI "-with-xcas"}";
|
||
|
|
version = "1.5.0-21"; # TODO try to remove preCheck phase on upgrade
|
||
|
|
|
||
|
|
src = fetchurl {
|
||
|
|
url = "https://www-fourier.ujf-grenoble.fr/~parisse/debian/dists/stable/main/source/giac_${version}.tar.gz";
|
||
|
|
sha256 = "1b9khiv0mk2xzw1rblm2jy6qsf8y6f9k7qy15sxpb21d72hzzbl2";
|
||
|
|
};
|
||
|
|
|
||
|
|
patches = stdenv.lib.optionals (!enableGUI) [
|
||
|
|
# when enableGui is false, giac is compiled without fltk. That means some
|
||
|
|
# outputs differ in the make check. Patch around this:
|
||
|
|
(fetchpatch {
|
||
|
|
url = "https://git.sagemath.org/sage.git/plain/build/pkgs/giac/patches/nofltk-check.patch?id=7553a3c8dfa7bcec07241a07e6a4e7dcf5bb4f26";
|
||
|
|
sha256 = "0xkmfc028vg5w6va04gp2x2iv31n8v4shd6vbyvk4blzgfmpj2cw";
|
||
|
|
})
|
||
|
|
];
|
||
|
|
|
||
|
|
postPatch = ''
|
||
|
|
for i in doc/*/Makefile*; do
|
||
|
|
substituteInPlace "$i" --replace "/bin/cp" "cp";
|
||
|
|
done;
|
||
|
|
'';
|
||
|
|
|
||
|
|
nativeBuildInputs = [
|
||
|
|
texlive.combined.scheme-small bison flex
|
||
|
|
];
|
||
|
|
|
||
|
|
# perl is only needed for patchShebangs fixup.
|
||
|
|
buildInputs = [
|
||
|
|
gmp mpfr pari ntl gsl blas mpfi glpk nauty
|
||
|
|
readline gettext libpng libao perl ecm
|
||
|
|
# gfortran.cc default output contains static libraries compiled without -fPIC
|
||
|
|
# we want libgfortran.so.3 instead
|
||
|
|
(stdenv.lib.getLib gfortran.cc)
|
||
|
|
lapack blas
|
||
|
|
] ++ stdenv.lib.optionals enableGUI [
|
||
|
|
libGL libGLU fltk xorg.libX11
|
||
|
|
];
|
||
|
|
|
||
|
|
/* fixes:
|
||
|
|
configure:16211: checking for main in -lntl
|
||
|
|
configure:16230: g++ -o conftest -g -O2 conftest.cpp -lntl -llapack -lblas -lgfortran -ldl -lpng16 -lm -lmpfi -lmpfr -lgmp >&5
|
||
|
|
/nix/store/y9c1v4x7y39j2rfbg17agjwqdzxpsn18-ntl-11.3.2/lib/libntl.so: undefined reference to `pthread_key_create'
|
||
|
|
*/
|
||
|
|
NIX_CFLAGS_LINK="-lpthread";
|
||
|
|
|
||
|
|
# xcas Phys and Turtle menus are broken with split outputs
|
||
|
|
# and interactive use is likely to need docs
|
||
|
|
outputs = [ "out" ] ++ stdenv.lib.optional (!enableGUI) "doc";
|
||
|
|
|
||
|
|
doCheck = true;
|
||
|
|
preCheck = ''
|
||
|
|
# One test in this file fails. That test just tests a part of the pari
|
||
|
|
# interface that isn't actually used in giac. Of course it would be better
|
||
|
|
# to only remove that one test, but that would require a patch.
|
||
|
|
# Removing the whole test set should be good enough for now.
|
||
|
|
# Upstream report: https://xcas.univ-grenoble-alpes.fr/forum/viewtopic.php?f=4&t=2102#p10326
|
||
|
|
echo > check/chk_fhan11
|
||
|
|
'';
|
||
|
|
|
||
|
|
enableParallelBuilding = true;
|
||
|
|
|
||
|
|
configureFlags = [
|
||
|
|
"--enable-gc" "--enable-png" "--enable-gsl" "--enable-lapack"
|
||
|
|
"--enable-pari" "--enable-ntl" "--enable-gmpxx" # "--enable-cocoa"
|
||
|
|
"--enable-ao" "--enable-ecm" "--enable-glpk"
|
||
|
|
] ++ stdenv.lib.optionals enableGUI [
|
||
|
|
"--enable-gui" "--with-x"
|
||
|
|
];
|
||
|
|
|
||
|
|
postInstall = ''
|
||
|
|
# example Makefiles contain the full path to some commands
|
||
|
|
# notably texlive, and we don't want texlive to become a runtime
|
||
|
|
# dependency
|
||
|
|
for file in $(find $out -name Makefile) ; do
|
||
|
|
sed -i "s@/nix/store/[^/]*/bin/@@" "$file" ;
|
||
|
|
done;
|
||
|
|
|
||
|
|
# reference cycle
|
||
|
|
rm "$out/share/giac/doc/el/"{casinter,tutoriel}/Makefile
|
||
|
|
|
||
|
|
if [ -n "$doc" ]; then
|
||
|
|
mkdir -p "$doc/share/giac"
|
||
|
|
mv "$out/share/giac/doc" "$doc/share/giac"
|
||
|
|
mv "$out/share/giac/examples" "$doc/share/giac"
|
||
|
|
fi
|
||
|
|
'' + stdenv.lib.optionalString (!enableGUI) ''
|
||
|
|
for i in pixmaps application-registry applications icons; do
|
||
|
|
rm -r "$out/share/$i";
|
||
|
|
done;
|
||
|
|
'';
|
||
|
|
|
||
|
|
meta = with stdenv.lib; {
|
||
|
|
description = "A free computer algebra system (CAS)";
|
||
|
|
homepage = "https://www-fourier.ujf-grenoble.fr/~parisse/giac.html";
|
||
|
|
license = licenses.gpl3Plus;
|
||
|
|
platforms = platforms.linux ++ (optionals (!enableGUI) platforms.darwin);
|
||
|
|
maintainers = [ maintainers.symphorien ];
|
||
|
|
};
|
||
|
|
}
|