{ pkgs, ... }:

let
  rev = "v0.22.0";
  src = (pkgs.fetchFromGitHub {
    owner = "martinvonz";
    repo = "jj";
    inherit rev;
    hash = "sha256-GbKmX1Ev/8di3A1XT5ZIRjzn2zP6DMye2NpA26PGVIs=";
  }) // {
    shortRev = rev;
  };
  flake-utils-src = (pkgs.fetchFromGitHub {
    owner = "numtide";
    repo = "flake-utils";
    rev = "v1.0.0";
    sha256 = "0hynd4rbkbplxzl2a8wb3r8z0h17z2alhhdsam78g3vgzpzg0d43";
  });
  flake-utils = (import "${flake-utils-src}/flake.nix").outputs {
    self = flake-utils;
  };
  rust-overlay-src = (pkgs.fetchFromGitHub {
    owner = "oxalica";
    repo = "rust-overlay";
    rev = "2b00881d2ff72174cffdc007238cb6bedd6e1d8e";
    hash = "sha256-+OB00N6Yql/ZRQQkQ0PNnxfW2tH89DHnv29hBS7tXMM=";
  });
  rust-overlay = (import "${rust-overlay-src}/flake.nix").outputs {
    self = rust-overlay;
    nixpkgs = pkgs;
  };
  flake = (import "${src}/flake.nix").outputs {
    self = flake;
    nixpkgs = pkgs.path;
    flake-utils = flake-utils;
    rust-overlay = rust-overlay;
  };
  fromFlake = (flake.overlays.default pkgs pkgs).jujutsu;
  fromFlake' = if pkgs.system == "aarch64-linux" then fromFlake.overrideAttrs (_: {
    doCheck = false;
  }) else fromFlake;
in
fromFlake'