# SPDX-FileCopyrightText: 2020 Luke Granger-Brown <depot@lukegb.com>
#
# SPDX-License-Identifier: Apache-2.0

{ pkgs, ... }:
let
  origImageArgs = {
    imageName = "octobus/heptapod";
    imageDigest = "sha256:c435bc56222396e69e6c4705861a0bbb48b9c457d3b6e8bfb7cfe9fa06b20d15";
    sha256 = "sha256:0zaz2qihsbr11js1wvyqxhfvpqklk6i3v3kr2v3y6zflpy66zcpj";
    finalImageName = "octobus/heptapod";
    finalImageTag = "0.25.2";
  };
  origImage = pkgs.dockerTools.pullImage origImageArgs;

  name = origImageArgs.imageName;
  tag = "${origImageArgs.finalImageTag}-lukegb";
in pkgs.dockerTools.buildImage rec {
  inherit name tag;
  fromImage = origImage;
  fromImageName = origImageArgs.finalImageName;
  fromImageTag = origImageArgs.finalImageTag;
  diskSize = 8192;
  runAsRoot = ''
    #!{pkgs.runtimeShell}
    cat <<"EOF" >/assets/wrapper_wrapper
    #!/bin/bash
    /usr/bin/id hg || /usr/sbin/useradd -g $(id -u git) -u $(id -g git) -o -d /var/opt/gitlab -p "*" hg
    /usr/bin/grep "AllowUsers git hg" /assets/sshd_config || /bin/sed -i "s/AllowUsers git/AllowUsers git hg/" /assets/sshd_config
    exec /assets/wrapper "$@"
    EOF
    chmod ugo=rx /assets/wrapper_wrapper
  '';
  config.Cmd = ["/assets/wrapper_wrapper"];
} // {
  meta = { inherit name tag; };
}