# SPDX-FileCopyrightText: 2020 Luke Granger-Brown <depot@lukegb.com>
#
# SPDX-License-Identifier: Apache-2.0

{ pkgs, ... }:
let
  origImageArgs = {
    imageName = "octobus/heptapod";
    imageDigest = "sha256:5731200e0e14cf38fdf555a815e8192ada9cbaf82b296edd39c70579247ef00d";
    sha256 = "sha256:00xr9pdwpkpdqi8lv77lkq1vj7j2gr00xndajh42hv8532by0n2k";
    finalImageName = "octobus/heptapod";
    finalImageTag = "0.23.2";
  };
  origImage = pkgs.dockerTools.pullImage origImageArgs;

  name = origImageArgs.imageName;
  tag = "${origImageArgs.finalImageTag}-lukegb";
in pkgs.dockerTools.buildImage rec {
  inherit name tag;
  fromImage = origImage;
  fromImageName = origImageArgs.finalImageName;
  fromImageTag = origImageArgs.finalImageTag;
  diskSize = 8192;
  runAsRoot = ''
    #!{pkgs.runtimeShell}
    cat <<"EOF" >/assets/wrapper_wrapper
    #!/bin/bash
    /usr/bin/id hg || /usr/sbin/useradd -g $(id -u git) -u $(id -g git) -o -d /var/opt/gitlab -p "*" hg
    /usr/bin/grep "AllowUsers git hg" /assets/sshd_config || /bin/sed -i "s/AllowUsers git/AllowUsers git hg/" /assets/sshd_config
    exec /assets/wrapper "$@"
    EOF
    chmod ugo=rx /assets/wrapper_wrapper
  '';
  config.Cmd = ["/assets/wrapper_wrapper"];
} // {
  meta = { inherit name tag; };
}