{ fetchFromGitLab
, pkgs
, lib
, stdenv
, makeWrapper
, python3
, nodejs-16_x
, ossOnly ? true
}:

let
  version = "1.13.3";
  suffix = lib.optionalString ossOnly "-oss";
  src' = fetchFromGitLab {
    owner = "bramw";
    repo = "baserow";
    rev = version;
    sha256 = "00fi5hqz55k08y7wwds42d1z6q1ax2hpb2x5fi1nyc3ymk7khr09";
  };
  src = if ossOnly then pkgs.runCommand "${src'.name}${suffix}" {} ''
    cp -R ${src'} $out
    chmod -R u+w $out
    rm -rf $out/premium
    rm -rf $out/enterprise

    sed -i -e '/baserow_premium/d' -e '/baserow_enterprise/d' $out/backend/src/baserow/config/settings/base.py
    sed -i -e '/premium/d' -e '/enterprise/d' $out/web-frontend/config/nuxt.config.base.js
  '' else src';
  web-frontend-deps = import ./web-frontend {
    inherit pkgs nodejs;
    inherit (pkgs) system;
    src = "${src}/web-frontend";
  };

  nodejs = nodejs-16_x;
  python = python3.override {
    packageOverrides = self: super:
      let
        oss = import ./backend/pynixify/overlay.nix self super;
        premium = import ./premium-backend/pynixify/overlay.nix self super;
        enterprise = import ./enterprise-backend/pynixify/overlay.nix self super;
        baserow-premium-backend = premium.baserow-premium-backend.overridePythonAttrs (_: {
          inherit version;
          src = "${src}/premium/backend";
          postInstall = ''
            install -m0644 $src/src/baserow_premium/public_key.pem $out/${python.sitePackages}/baserow_premium/public_key.pem
          '';
        });
        baserow-enterprise-backend = enterprise.baserow-enterprise-backend.overridePythonAttrs (_: {
          inherit version;
          src = "${src}/enterprise/backend";
          postPatch = ''
            pushd src/baserow_enterprise
            find . -name '*.py' -printf '%h\n' | sort | uniq | while read pydir; do
              thisdir=$pydir
              while [[ "$thisdir" != "." ]]; do
                test -f $thisdir/__init__.py || touch $thisdir/__init__.py
                thisdir="$(dirname $thisdir)"
              done
            done
            popd
          '';
        });
      in
        oss // (if !ossOnly then premium else {}) // {
          baserow-backend = oss.baserow-backend.overridePythonAttrs (oldAttrs: {
            inherit version;
            src = "${src}/backend";
            prePatch = ''
              # Yeet. Just assume everything is installed in the environment already.
              > requirements/base.txt
            '';
            propagatedBuildInputs = oldAttrs.propagatedBuildInputs ++ lib.optionals (!ossOnly) [ baserow-premium-backend baserow-enterprise-backend ];
          });
        } // (if !ossOnly then { inherit baserow-premium-backend baserow-enterprise-backend; } else {});
  };
in
{
  inherit src web-frontend-deps python;

  web-frontend = stdenv.mkDerivation {
    name = "baserow${suffix}-web-frontend";
    inherit src version;
    buildInputs = [ nodejs ];
    nativeBuildInputs = [ makeWrapper ];
    nodeDependencies = web-frontend-deps.shell.nodeDependencies;
    buildPhase = ''
      runHook preBuild

      outpath="$out/share/baserow"
      mkdir -p $outpath
      cp -R web-frontend $outpath/web-frontend

      ${lib.optionalString (!ossOnly) ''
        mkdir -p $outpath/premium
        cp -R premium/web-frontend $outpath/premium/web-frontend

        mkdir -p $outpath/enterprise
        cp -R enterprise/web-frontend $outpath/enterprise/web-frontend
      ''}

      # Disable prompts
      export MINIMAL=true
      export NODE_OPTIONS=--openssl-legacy-provider

      pushd $outpath/web-frontend
      mkdir node_modules
      for f in $nodeDependencies/lib/node_modules/*; do
        ln -s "$f" ./node_modules
      done
      export PATH="$nodeDependencies/bin:$PATH"
      ./node_modules/nuxt/bin/nuxt.js build --config-file config/nuxt.config.local.js
      popd

      mkdir $out/bin
      makeWrapper $nodeDependencies/lib/node_modules/nuxt/bin/nuxt.js $out/bin/baserow-web-frontend \
        --run "cd $outpath/web-frontend" \
        --add-flags "start --config-file config/nuxt.config.local.js"

      runHook postBuild
    '';
    dontInstall = true;
  };

  backend = python.pkgs.baserow-backend.overridePythonAttrs (oldAttrs: {
    inherit version;
    src = "${src}/backend";
    prePatch = ''
      # Yeet. Just assume everything is installed in the environment already.
      > requirements/base.txt

      substituteInPlace src/baserow/config/settings/base.py \
        --replace 'APPLICATION_TEMPLATES_DIR = os.path.join(BASE_DIR, "../../../templates")' "APPLICATION_TEMPLATES_DIR = '$out/share/baserow/templates'"
    '';
    postInstall = ''
      comm -23 <(find $src/src/baserow/ -type d | sed "s,$src/src/baserow/,," | sort) <(find $out/${python.sitePackages}/baserow/ -type d | sed "s,$out/${python.sitePackages}/baserow/,," | sort) | while read missingDir; do
        test -e "$out/${python.sitePackages}/baserow/$missingDir" && continue
        cp -R "$src/src/baserow/$missingDir" "$out/${python.sitePackages}/baserow/$missingDir"
      done

      install -d -m 0755 $out/share/baserow
      cp -R "$src/templates" "$out/share/baserow/templates"

      install -m 0755 ${./backend/gunicorn.py} $out/bin/baserow-gunicorn
      install -m 0755 ${./backend/celery.py} $out/bin/baserow-celery
    '';
  });
}