{ pkgs, depot, lib, config, ... }:
{
  imports = [ ./client.nix ];

  options.my.alacritty = with lib; {
    fontSize = mkOption {
      default = 6;
      type = types.int;
    };
  };

  config = {
    gtk = {
      enable = true;
      gtk3.extraConfig = {
        gtk-application-prefer-dark-theme = 1;
      };
    };
    qt = {
      enable = true;
      platformTheme = "gtk";
    };

    home.packages = lib.mkAfter (with pkgs; [
      google-chrome-beta
      firefox
      mpv
      dino
      lutris
      pavucontrol
      pngquant
      rxvt_unicode
      teamspeak_client
      virtmanager
      xclip
      xss-lock
      yubioath-desktop
      depot.nix.pkgs.flameshot
    ]);

    programs.alacritty = {
      enable = true;
      settings.font = let
        iosevka = style: { family = "Iosevka"; inherit style; };
      in {
        normal = iosevka "Regular";
        bold = iosevka "Bold";
        italic = iosevka "Italic";
        bold_italic = iosevka "Bold Italic";
        size = config.my.alacritty.fontSize;
      };
      settings.colors = {
        # Ayu Dark, from https://github.com/alacritty/alacritty/wiki/Color-schemes
        primary = {
          background = "#0A0E14";
          foreground = "#B3B1AD";
        };

        # Normal colors
        normal = {
          black = "#01060E";
          red = "#EA6C73";
          green = "#91B362";
          yellow = "#F9AF4F";
          blue = "#53BDFA";
          magenta = "#FAE994";
          cyan = "#90E1C6";
          white = "#C7C7C7";
        };

        # Bright colors
        bright = {
          black = "#686868";
          red = "#F07178";
          green = "#C2D94C";
          yellow = "#FFB454";
          blue = "#59C2FF";
          magenta = "#FFEE99";
          cyan = "#95E6CB";
          white = "#FFFFFF";
        };
      };
    };

    home.file."bin/screencap" = {
      executable = true;
      text = ''
        #!/usr/bin/env bash
        exec ${depot.nix.pkgs.flameshot}/bin/flameshot gui
      '';
    };
    home.file.".xprofile".text = ''
      . "${config.home.profileDirectory}/etc/profile.d/hm-session-vars.sh"

      if [ -e "$HOME/.profile" ]; then
        . "$HOME/.profile"
      fi

      systemctl --user import-environment DBUS_SESSION_BUS_ADDRESS DISPLAY XAUTHORITY XDG_DATA_DIRS XDG_RUNTIME_DIR XDG_SESSION_ID
      systemctl --user restart ssh-agent
    '';
  };
}