51 lines
1.3 KiB
Nix
51 lines
1.3 KiB
Nix
{ config, lib, ... }:
|
|
with lib;
|
|
let
|
|
cfg = config.hardware.cpu.amd.sev;
|
|
defaultGroup = "sev";
|
|
in
|
|
with lib; {
|
|
options.hardware.cpu.amd.sev = {
|
|
enable = mkEnableOption "access to the AMD SEV device";
|
|
user = mkOption {
|
|
description = "Owner to assign to the SEV device.";
|
|
type = types.str;
|
|
default = "root";
|
|
};
|
|
group = mkOption {
|
|
description = "Group to assign to the SEV device.";
|
|
type = types.str;
|
|
default = defaultGroup;
|
|
};
|
|
mode = mkOption {
|
|
description = "Mode to set for the SEV device.";
|
|
type = types.str;
|
|
default = "0660";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
{
|
|
assertion = hasAttr cfg.user config.users.users;
|
|
message = "Given user does not exist";
|
|
}
|
|
{
|
|
assertion = (cfg.group == defaultGroup) || (hasAttr cfg.group config.users.groups);
|
|
message = "Given group does not exist";
|
|
}
|
|
];
|
|
|
|
boot.extraModprobeConfig = ''
|
|
options kvm_amd sev=1
|
|
'';
|
|
|
|
users.groups = optionalAttrs (cfg.group == defaultGroup) {
|
|
"${cfg.group}" = {};
|
|
};
|
|
|
|
services.udev.extraRules = with cfg; ''
|
|
KERNEL=="sev", OWNER="${user}", GROUP="${group}", MODE="${mode}"
|
|
'';
|
|
};
|
|
}
|