45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
{ lib, fetchFromGitHub, buildLinux, ... } @ args:
|
|
|
|
let
|
|
# comments with variant added for update script
|
|
# ./update-zen.py zen
|
|
zenVariant = {
|
|
version = "6.1.6"; #zen
|
|
suffix = "zen1"; #zen
|
|
sha256 = "14f24w8cww1096lawrk0absx6sqy4mm0f2wpsijgjx4br2ln7p4r"; #zen
|
|
isLqx = false;
|
|
};
|
|
# ./update-zen.py lqx
|
|
lqxVariant = {
|
|
version = "6.1.6"; #lqx
|
|
suffix = "lqx1"; #lqx
|
|
sha256 = "0w1ckias1j1baidyw1a6kq1za7i3ig0w1phkb4s7sw9p7bnhbrx1"; #lqx
|
|
isLqx = true;
|
|
};
|
|
zenKernelsFor = { version, suffix, sha256, isLqx }: buildLinux (args // {
|
|
inherit version;
|
|
modDirVersion = lib.versions.pad 3 "${version}-${suffix}";
|
|
isZen = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zen-kernel";
|
|
repo = "zen-kernel";
|
|
rev = "v${version}-${suffix}";
|
|
inherit sha256;
|
|
};
|
|
|
|
passthru.updateScript = [ ./update-zen.py (if isLqx then "lqx" else "zen") ];
|
|
|
|
extraMeta = {
|
|
branch = lib.versions.majorMinor version + "/master";
|
|
maintainers = with lib.maintainers; [ andresilva pedrohlc ];
|
|
description = "Built using the best configuration and kernel sources for desktop, multimedia, and gaming workloads." +
|
|
lib.optionalString isLqx " (Same as linux_zen but less aggressive release schedule)";
|
|
};
|
|
|
|
} // (args.argsOverride or { }));
|
|
in
|
|
{
|
|
zen = zenKernelsFor zenVariant;
|
|
lqx = zenKernelsFor lqxVariant;
|
|
}
|