51 lines
1.2 KiB
Nix
51 lines
1.2 KiB
Nix
{ lib, fetchFromGitHub, buildGoModule, installShellFiles }:
|
|
|
|
buildGoModule rec {
|
|
pname = "gh";
|
|
version = "1.12.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "cli";
|
|
repo = "cli";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-P9fbkJSXRYZdVD1EKWWs0FKs8aQdPqHWESUqjsGgyPU=";
|
|
};
|
|
|
|
vendorSha256 = "sha256-ndsjmY/UCFyegm8yP7BopYMh5eZ8/fftWfxW4r5los0=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
# upstream unsets these to handle cross but it breaks our build
|
|
postPatch = ''
|
|
substituteInPlace Makefile \
|
|
--replace "GOOS= GOARCH= GOARM= GOFLAGS= CGO_ENABLED=" ""
|
|
'';
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
make GO_LDFLAGS="-s -w" GH_VERSION=${version} bin/gh manpages
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm755 bin/gh -t $out/bin
|
|
installManPage share/man/*/*.[1-9]
|
|
|
|
for shell in bash fish zsh; do
|
|
$out/bin/gh completion -s $shell > gh.$shell
|
|
installShellCompletion gh.$shell
|
|
done
|
|
runHook postInstall
|
|
'';
|
|
|
|
# fails with `unable to find git executable in PATH`
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "GitHub CLI tool";
|
|
homepage = "https://cli.github.com/";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ zowoq ];
|
|
};
|
|
}
|