193 lines
4.3 KiB
Nix
193 lines
4.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, nix-update-script
|
|
, wrapQtAppsHook
|
|
, alsa-lib
|
|
, boost
|
|
, catch2_3
|
|
, cmake
|
|
, compat-list
|
|
, cpp-jwt
|
|
, cubeb
|
|
, discord-rpc
|
|
, doxygen
|
|
, enet
|
|
, ffmpeg
|
|
, fmt
|
|
, glslang
|
|
, httplib
|
|
, inih
|
|
, libjack2
|
|
, libopus
|
|
, libpulseaudio
|
|
, libusb1
|
|
, libva
|
|
, libzip
|
|
, lz4
|
|
, nlohmann_json
|
|
, nx_tzdb
|
|
, perl
|
|
, pkg-config
|
|
, python3
|
|
, qtbase
|
|
, qtmultimedia
|
|
, qttools
|
|
, qtwayland
|
|
, qtwebengine
|
|
, rapidjson
|
|
, SDL2
|
|
, sndio
|
|
, speexdsp
|
|
, udev
|
|
, vulkan-headers
|
|
, vulkan-loader
|
|
, zlib
|
|
, zstd
|
|
}:
|
|
stdenv.mkDerivation(finalAttrs: {
|
|
pname = "yuzu";
|
|
version = "1665";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "yuzu-emu";
|
|
repo = "yuzu-mainline";
|
|
rev = "mainline-0-${finalAttrs.version}";
|
|
hash = "sha256-xzSup1oz83GPpOGh9aJJ5YjoFX/cBI8RV6SvDYNH/zA=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
doxygen
|
|
perl
|
|
pkg-config
|
|
python3
|
|
wrapQtAppsHook
|
|
];
|
|
|
|
buildInputs = [
|
|
# vulkan-headers must come first, so the older propagated versions
|
|
# don't get picked up by accident
|
|
vulkan-headers
|
|
|
|
alsa-lib
|
|
boost
|
|
catch2_3
|
|
cpp-jwt
|
|
cubeb
|
|
discord-rpc
|
|
# intentionally omitted: dynarmic - prefer vendored version for compatibility
|
|
enet
|
|
ffmpeg
|
|
fmt
|
|
glslang
|
|
httplib
|
|
inih
|
|
libjack2
|
|
libopus
|
|
libpulseaudio
|
|
libusb1
|
|
libva
|
|
libzip
|
|
# intentionally omitted: LLVM - heavy, only used for stack traces in the debugger
|
|
lz4
|
|
nlohmann_json
|
|
qtbase
|
|
qtmultimedia
|
|
qttools
|
|
qtwayland
|
|
qtwebengine
|
|
rapidjson
|
|
SDL2
|
|
sndio
|
|
speexdsp
|
|
udev
|
|
# intentionally omitted: xbyak - prefer vendored version for compatibility
|
|
zlib
|
|
zstd
|
|
];
|
|
|
|
# This changes `ir/opt` to `ir/var/empty` in `externals/dynarmic/src/dynarmic/CMakeLists.txt`
|
|
# making the build fail, as that path does not exist
|
|
dontFixCmake = true;
|
|
|
|
cmakeFlags = [
|
|
# actually has a noticeable performance impact
|
|
"-DYUZU_ENABLE_LTO=ON"
|
|
|
|
# build with qt6
|
|
"-DENABLE_QT6=ON"
|
|
"-DENABLE_QT_TRANSLATION=ON"
|
|
|
|
# use system libraries
|
|
# NB: "external" here means "from the externals/ directory in the source",
|
|
# so "off" means "use system"
|
|
"-DYUZU_USE_EXTERNAL_SDL2=OFF"
|
|
"-DYUZU_USE_EXTERNAL_VULKAN_HEADERS=OFF"
|
|
|
|
# don't check for missing submodules
|
|
"-DYUZU_CHECK_SUBMODULES=OFF"
|
|
|
|
# enable some optional features
|
|
"-DYUZU_USE_QT_WEB_ENGINE=ON"
|
|
"-DYUZU_USE_QT_MULTIMEDIA=ON"
|
|
"-DUSE_DISCORD_PRESENCE=ON"
|
|
|
|
# We dont want to bother upstream with potentially outdated compat reports
|
|
"-DYUZU_ENABLE_COMPATIBILITY_REPORTING=OFF"
|
|
"-DENABLE_COMPATIBILITY_LIST_DOWNLOAD=OFF" # We provide this deterministically
|
|
];
|
|
|
|
# Fixes vulkan detection.
|
|
# FIXME: patchelf --add-rpath corrupts the binary for some reason, investigate
|
|
qtWrapperArgs = [
|
|
"--prefix LD_LIBRARY_PATH : ${vulkan-loader}/lib"
|
|
];
|
|
|
|
preConfigure = ''
|
|
# see https://github.com/NixOS/nixpkgs/issues/114044, setting this through cmakeFlags does not work.
|
|
cmakeFlagsArray+=(
|
|
"-DTITLE_BAR_FORMAT_IDLE=${finalAttrs.pname} | ${finalAttrs.version} (nixpkgs) {}"
|
|
"-DTITLE_BAR_FORMAT_RUNNING=${finalAttrs.pname} | ${finalAttrs.version} (nixpkgs) | {}"
|
|
)
|
|
|
|
# provide pre-downloaded tz data
|
|
mkdir -p build/externals/nx_tzdb
|
|
ln -sf ${nx_tzdb} build/externals/nx_tzdb/${nx_tzdb.version}.zip
|
|
'';
|
|
|
|
# This must be done after cmake finishes as it overwrites the file
|
|
postConfigure = ''
|
|
ln -sf ${compat-list} ./dist/compatibility_list/compatibility_list.json
|
|
'';
|
|
|
|
passthru.updateScript = nix-update-script {
|
|
extraArgs = [ "--version-regex" "mainline-0-(.*)" ];
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://yuzu-emu.org";
|
|
changelog = "https://yuzu-emu.org/entry";
|
|
description = "An experimental Nintendo Switch emulator written in C++";
|
|
longDescription = ''
|
|
An experimental Nintendo Switch emulator written in C++.
|
|
Using the mainline branch is recommended for general usage.
|
|
Using the early-access branch is recommended if you would like to try out experimental features, with a cost of stability.
|
|
'';
|
|
mainProgram = "yuzu";
|
|
platforms = [ "x86_64-linux" ];
|
|
license = with licenses; [
|
|
gpl3Plus
|
|
# Icons
|
|
asl20 mit cc0
|
|
];
|
|
maintainers = with maintainers; [
|
|
ashley
|
|
ivar
|
|
joshuafern
|
|
sbruder
|
|
k900
|
|
];
|
|
};
|
|
})
|