45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
{ lib, fetchFromGitHub, buildLinux, ... } @ args:
|
|
|
|
let
|
|
# comments with variant added for update script
|
|
# ./update-zen.py zen
|
|
zenVariant = {
|
|
version = "5.19.11"; #zen
|
|
suffix = "zen1"; #zen
|
|
sha256 = "0slrbsqdvnlnk2hr356wjmbhh8qkn39k34jn1lidhjyfb9c7fg6a"; #zen
|
|
isLqx = false;
|
|
};
|
|
# ./update-zen.py lqx
|
|
lqxVariant = {
|
|
version = "5.19.11"; #lqx
|
|
suffix = "lqx2"; #lqx
|
|
sha256 = "1j6mr3ibl99l23wyycs5m1zmclp1qwbw5in36hi0pfq04jx2l6cn"; #lqx
|
|
isLqx = true;
|
|
};
|
|
zenKernelsFor = { version, suffix, sha256, isLqx }: buildLinux (args // {
|
|
inherit version;
|
|
modDirVersion = "${lib.concatStringsSep "." (lib.take 3 (lib.splitVersion version ++ [ "0" "0" ]))}-${suffix}";
|
|
isZen = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zen-kernel";
|
|
repo = "zen-kernel";
|
|
rev = "v${version}-${suffix}";
|
|
inherit sha256;
|
|
};
|
|
|
|
passthru.updateScript = [ ./update-zen.py (if isLqx then "lqx" else "zen") ];
|
|
|
|
extraMeta = {
|
|
branch = lib.versions.majorMinor version + "/master";
|
|
maintainers = with lib.maintainers; [ andresilva pedrohlc ];
|
|
description = "Built using the best configuration and kernel sources for desktop, multimedia, and gaming workloads." +
|
|
lib.optionalString isLqx " (Same as linux_zen but less aggressive release schedule)";
|
|
};
|
|
|
|
} // (args.argsOverride or { }));
|
|
in
|
|
{
|
|
zen = zenKernelsFor zenVariant;
|
|
lqx = zenKernelsFor lqxVariant;
|
|
}
|