depot/pkgs/applications/misc/oil-buku/default.nix
Luke Granger-Brown 57725ef3ec Squashed 'third_party/nixpkgs/' content from commit 76612b17c0ce
git-subtree-dir: third_party/nixpkgs
git-subtree-split: 76612b17c0ce71689921ca12d9ffdc9c23ce40b2
2024-11-10 23:59:47 +00:00

45 lines
1.2 KiB
Nix

{ stdenvNoCC, lib, fetchFromGitHub, jq, gawk, peco, makeWrapper }:
stdenvNoCC.mkDerivation rec {
pname = "oil-buku";
version = "0.3.2";
src = fetchFromGitHub {
owner = "AndreiUlmeyda";
repo = "oil";
rev = version;
sha256 = "12g0fd7h11hh94b2pyg3pqwbf8bc7gcnrnm1qqbf18s6z02b6ixr";
};
postPatch = ''
substituteInPlace src/oil --replace \
"LIBDIR=/usr/local/lib/oil" "LIBDIR=${placeholder "out"}/lib"
substituteInPlace src/json-to-line.jq --replace \
"/usr/bin/env -S jq" "${jq}/bin/jq"
substituteInPlace src/format-columns.awk --replace \
"/usr/bin/env -S awk" "${gawk}/bin/awk"
'';
makeFlags = [
"BINDIR=${placeholder "out"}/bin"
"LIBDIR=${placeholder "out"}/lib"
];
nativeBuildInputs = [ makeWrapper ];
postFixup = ''
wrapProgram $out/bin/oil \
--prefix PATH : ${lib.makeBinPath [ peco ]}
'';
meta = with lib; {
description = "Search-as-you-type cli frontend for the buku bookmarks manager using peco";
homepage = "https://github.com/AndreiUlmeyda/oil";
license = licenses.gpl3Only;
maintainers = with maintainers; [ atila ];
mainProgram = "oil";
platforms = platforms.unix;
};
}