51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{ lib, buildGoPackage, fetchFromGitLab, fetchurl }:
|
|
|
|
let
|
|
version = "12.10.2";
|
|
# Gitlab runner embeds some docker images these are prebuilt for arm and x86_64
|
|
docker_x86_64 = fetchurl {
|
|
url = "https://gitlab-runner-downloads.s3.amazonaws.com/v${version}/helper-images/prebuilt-x86_64.tar.xz";
|
|
sha256 = "1lw0f3svzsvcw1rkc8z60nrl2jqjj8ciqlw5icazf6ikqbqmf660";
|
|
};
|
|
|
|
docker_arm = fetchurl {
|
|
url = "https://gitlab-runner-downloads.s3.amazonaws.com/v${version}/helper-images/prebuilt-arm.tar.xz";
|
|
sha256 = "1hawdihnwk9p06fa3ym5q6b4sv6pp9095nimdy5myi6y88yj1rv2";
|
|
};
|
|
in
|
|
buildGoPackage rec {
|
|
inherit version;
|
|
pname = "gitlab-runner";
|
|
goPackagePath = "gitlab.com/gitlab-org/gitlab-runner";
|
|
commonPackagePath = "${goPackagePath}/common";
|
|
buildFlagsArray = ''
|
|
-ldflags=
|
|
-X ${commonPackagePath}.NAME=gitlab-runner
|
|
-X ${commonPackagePath}.VERSION=${version}
|
|
-X ${commonPackagePath}.REVISION=v${version}
|
|
'';
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "gitlab-org";
|
|
repo = "gitlab-runner";
|
|
rev = "v${version}";
|
|
sha256 = "1r82xj4krdd51540bhr2wjhp6sdr5c2favnnw8nl26vnmwiqpd3k";
|
|
};
|
|
|
|
patches = [ ./fix-shell-path.patch ];
|
|
|
|
postInstall = ''
|
|
touch $out/bin/hello
|
|
install -d $out/bin/helper-images
|
|
ln -sf ${docker_x86_64} $out/bin/helper-images/prebuilt-x86_64.tar.xz
|
|
ln -sf ${docker_arm} $out/bin/helper-images/prebuilt-arm.tar.xz
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "GitLab Runner the continuous integration executor of GitLab";
|
|
license = licenses.mit;
|
|
homepage = "https://about.gitlab.com/gitlab-ci/";
|
|
platforms = platforms.unix ++ platforms.darwin;
|
|
maintainers = with maintainers; [ bachp zimbatm globin ];
|
|
};
|
|
}
|