92 lines
2.6 KiB
Nix
92 lines
2.6 KiB
Nix
{ lib
|
|
, python3
|
|
, groff
|
|
, less
|
|
, fetchFromGitHub
|
|
}:
|
|
let
|
|
py = python3.override {
|
|
packageOverrides = self: super: {
|
|
botocore = super.botocore.overridePythonAttrs (oldAttrs: rec {
|
|
version = "2.0.0dev75";
|
|
src = fetchFromGitHub {
|
|
owner = "boto";
|
|
repo = "botocore";
|
|
rev = "1a4caa8d1c232e9463febec406a8fedc71cb065c";
|
|
sha256 = "0z2c9i2ci3f8979si8gcgnsz44ylchjax1f3dhj7pzyb2kcw6zri";
|
|
};
|
|
});
|
|
prompt_toolkit = super.prompt_toolkit.overridePythonAttrs (oldAttrs: rec {
|
|
version = "2.0.10";
|
|
src = oldAttrs.src.override {
|
|
inherit version;
|
|
sha256 = "1nr990i4b04rnlw1ghd0xmgvvvhih698mb6lb6jylr76cs7zcnpi";
|
|
};
|
|
});
|
|
};
|
|
};
|
|
|
|
in
|
|
with py.pkgs; buildPythonApplication rec {
|
|
pname = "awscli2";
|
|
version = "2.1.7"; # N.B: if you change this, change botocore to a matching version too
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "aws";
|
|
repo = "aws-cli";
|
|
rev = version;
|
|
sha256 = "0sxdbc8y5yqcvsk2bxkywdh4fsq90vlsmcm45y0sa3rpza64xs3r";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace setup.py --replace "colorama>=0.2.5,<0.4.4" "colorama>=0.2.5"
|
|
substituteInPlace setup.py --replace "cryptography>=2.8.0,<=2.9.0" "cryptography>=2.8.0"
|
|
substituteInPlace setup.py --replace "docutils>=0.10,<0.16" "docutils>=0.10"
|
|
substituteInPlace setup.py --replace "ruamel.yaml>=0.15.0,<0.16.0" "ruamel.yaml>=0.15.0"
|
|
substituteInPlace setup.py --replace "wcwidth<0.2.0" "wcwidth"
|
|
'';
|
|
|
|
# No tests included
|
|
doCheck = false;
|
|
|
|
propagatedBuildInputs = [
|
|
bcdoc
|
|
botocore
|
|
colorama
|
|
cryptography
|
|
distro
|
|
docutils
|
|
groff
|
|
less
|
|
prompt_toolkit
|
|
pyyaml
|
|
rsa
|
|
ruamel_yaml
|
|
s3transfer
|
|
six
|
|
wcwidth
|
|
];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/${python3.sitePackages}/awscli/data
|
|
${python3.interpreter} scripts/gen-ac-index --index-location $out/${python3.sitePackages}/awscli/data/ac.index
|
|
|
|
mkdir -p $out/share/bash-completion/completions
|
|
echo "complete -C $out/bin/aws_completer aws" > $out/share/bash-completion/completions/aws
|
|
|
|
mkdir -p $out/share/zsh/site-functions
|
|
mv $out/bin/aws_zsh_completer.sh $out/share/zsh/site-functions
|
|
|
|
rm $out/bin/aws.cmd
|
|
'';
|
|
|
|
passthru.python = py; # for aws_shell
|
|
|
|
meta = with lib; {
|
|
homepage = "https://docs.aws.amazon.com/cli/latest/userguide/install-cliv2.html";
|
|
changelog = "https://github.com/aws/aws-cli/blob/${version}/CHANGELOG.rst";
|
|
description = "Unified tool to manage your AWS services";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ bhipple davegallant ];
|
|
};
|
|
}
|