47 lines
1.4 KiB
Nix
47 lines
1.4 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, makeWrapper, iptables, iproute }:
|
|
|
|
buildGoModule rec {
|
|
pname = "tailscale";
|
|
version = "1.4.2";
|
|
tagHash = "f40ccb086c4c3f09b3cc67b7c559bd2c5d3cf953"; # from `git rev-parse v1.4.2`
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "tailscale";
|
|
repo = "tailscale";
|
|
rev = "v${version}";
|
|
sha256 = "0jc7z6ml59a1xs3c3mskj9s34gw7hmixn8dbz3bi81qv0yi9pvnx";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
CGO_ENABLED = 0;
|
|
|
|
vendorSha256 = "16aa7jc2h59hnnh0mfmnd0k198dijm9j4c44j80wpzlhf4x27yjs";
|
|
|
|
doCheck = false;
|
|
|
|
subPackages = [ "cmd/tailscale" "cmd/tailscaled" ];
|
|
|
|
preBuild = ''
|
|
export buildFlagsArray=(
|
|
-tags="xversion"
|
|
-ldflags="-X tailscale.com/version.Long=${version} -X tailscale.com/version.Short=${version} -X tailscale.com/version.GitCommit=${tagHash}"
|
|
)
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/tailscaled --prefix PATH : ${
|
|
lib.makeBinPath [ iproute iptables ]
|
|
}
|
|
sed -i -e "s#/usr/sbin#$out/bin#" -e "/^EnvironmentFile/d" ./cmd/tailscaled/tailscaled.service
|
|
install -D -m0444 -t $out/lib/systemd/system ./cmd/tailscaled/tailscaled.service
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://tailscale.com";
|
|
description = "The node agent for Tailscale, a mesh VPN built on WireGuard";
|
|
platforms = platforms.linux;
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ danderson mbaillie ];
|
|
};
|
|
}
|