45 lines
1.2 KiB
Nix
45 lines
1.2 KiB
Nix
{ lib, stdenv, fetchCrate, rustPlatform }:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "skim";
|
|
version = "0.10.1";
|
|
|
|
src = fetchCrate {
|
|
inherit pname version;
|
|
sha256 = "sha256-gC4/oQpK9m6/p1DY2Kabk5l7vsS9iafW3E5dgO723B8=";
|
|
};
|
|
|
|
outputs = [ "out" "vim" ];
|
|
|
|
cargoSha256 = "sha256-aNEfKHpNWDHebioUkEq6D0aL3Jf9NQXBuoWvpB7uO5U=";
|
|
|
|
postPatch = ''
|
|
sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/skim.vim
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -D -m 555 bin/sk-tmux -t $out/bin
|
|
install -D -m 644 man/man1/* -t $out/man/man1
|
|
install -D -m 444 shell/* -t $out/share/skim
|
|
install -D -m 444 plugin/skim.vim -t $vim/plugin
|
|
|
|
cat <<SCRIPT > $out/bin/sk-share
|
|
#! ${stdenv.shell}
|
|
# Run this script to find the skim shared folder where all the shell
|
|
# integration scripts are living.
|
|
echo $out/share/skim
|
|
SCRIPT
|
|
chmod +x $out/bin/sk-share
|
|
'';
|
|
|
|
# https://github.com/lotabout/skim/issues/440
|
|
doCheck = !stdenv.isAarch64;
|
|
|
|
meta = with lib; {
|
|
description = "Command-line fuzzy finder written in Rust";
|
|
homepage = "https://github.com/lotabout/skim";
|
|
license = licenses.mit;
|
|
mainProgram = "sk";
|
|
maintainers = with maintainers; [ dywedir ];
|
|
};
|
|
}
|