80 lines
1.9 KiB
Nix
80 lines
1.9 KiB
Nix
{ lib
|
|
, python
|
|
, enableTelemetry ? false
|
|
}:
|
|
|
|
let
|
|
py = python.override {
|
|
packageOverrides = self: super: {
|
|
flask = super.flask.overridePythonAttrs (oldAttrs: rec {
|
|
version = "1.0.2";
|
|
src = oldAttrs.src.override {
|
|
inherit version;
|
|
sha256 = "0j6f4a9rpfh25k1gp7azqhnni4mb4fgy50jammgjgddw1l3w0w92";
|
|
};
|
|
});
|
|
|
|
cookiecutter = super.cookiecutter.overridePythonAttrs (oldAttrs: rec {
|
|
version = "1.6.0";
|
|
src = oldAttrs.src.override {
|
|
inherit version;
|
|
sha256 = "0glsvaz8igi2wy1hsnhm9fkn6560vdvdixzvkq6dn20z3hpaa5hk";
|
|
};
|
|
});
|
|
};
|
|
};
|
|
|
|
in
|
|
|
|
with py.pkgs;
|
|
|
|
buildPythonApplication rec {
|
|
pname = "aws-sam-cli";
|
|
version = "0.44.0";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "0r3m41xjmg8m2jwsqwc9kdkcs3xbz8dsl240ybwbnr7rp29pnirf";
|
|
};
|
|
|
|
# Tests are not included in the PyPI package
|
|
doCheck = false;
|
|
|
|
propagatedBuildInputs = [
|
|
aws-lambda-builders
|
|
aws-sam-translator
|
|
chevron
|
|
click
|
|
cookiecutter
|
|
dateparser
|
|
docker
|
|
flask
|
|
idna
|
|
jmespath
|
|
pathlib2
|
|
requests
|
|
serverlessrepo
|
|
six
|
|
tomlkit
|
|
];
|
|
|
|
postFixup = if enableTelemetry then "echo aws-sam-cli TELEMETRY IS ENABLED" else ''
|
|
# Disable telemetry: https://github.com/awslabs/aws-sam-cli/issues/1272
|
|
wrapProgram $out/bin/sam --set SAM_CLI_TELEMETRY 0
|
|
'';
|
|
|
|
# fix over-restrictive version bounds
|
|
postPatch = ''
|
|
substituteInPlace requirements/base.txt \
|
|
--replace "serverlessrepo==0.1.9" "serverlessrepo~=0.1.9" \
|
|
--replace "python-dateutil~=2.6, <2.8.1" "python-dateutil~=2.6" \
|
|
--replace "tomlkit==0.5.8" "tomlkit~=0.5.8" \
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/awslabs/aws-sam-cli";
|
|
description = "CLI tool for local development and testing of Serverless applications";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ andreabedini lo1tuma ];
|
|
};
|
|
}
|