68 lines
2.6 KiB
Nix
68 lines
2.6 KiB
Nix
{ lib, stdenv, callPackage, fetchurl, nixosTests, commandLineArgs ? "", useVSCodeRipgrep ? stdenv.isDarwin }:
|
|
|
|
let
|
|
inherit (stdenv.hostPlatform) system;
|
|
throwSystem = throw "Unsupported system: ${system}";
|
|
|
|
plat = {
|
|
x86_64-linux = "linux-x64";
|
|
x86_64-darwin = "darwin-x64";
|
|
aarch64-linux = "linux-arm64";
|
|
aarch64-darwin = "darwin-arm64";
|
|
armv7l-linux = "linux-armhf";
|
|
}.${system} or throwSystem;
|
|
|
|
archive_fmt = if stdenv.isDarwin then "zip" else "tar.gz";
|
|
|
|
sha256 = {
|
|
x86_64-linux = "0y9gs7w330l8x21l2qr5ki46aqmz22v17kmaisj5z5lgyfqyyf97";
|
|
x86_64-darwin = "1i1c0axlipp12b3y3sl6liq4cs7ybjflm8jnrwf9wrrvq7d911bn";
|
|
aarch64-linux = "03894hcjsvskp3s1gl1cmnvy7s7x8iz4z6pz5wk7aayw0j03f3zh";
|
|
aarch64-darwin = "0n59dpc18abq42y1sb5wdrbv9n8pwnyhlcsrjx41r9ykmfk8cvih";
|
|
armv7l-linux = "0iiw5rdw2gsr5y45i00ri858ylm6q4jdk3vh7g0f0vv4csprx5c3";
|
|
}.${system} or throwSystem;
|
|
|
|
sourceRoot = if stdenv.isDarwin then "" else ".";
|
|
in
|
|
callPackage ./generic.nix rec {
|
|
inherit sourceRoot commandLineArgs useVSCodeRipgrep;
|
|
|
|
# Please backport all compatible updates to the stable release.
|
|
# This is important for the extension ecosystem.
|
|
version = "1.80.0.23188";
|
|
pname = "vscodium";
|
|
|
|
executableName = "codium";
|
|
longName = "VSCodium";
|
|
shortName = "vscodium";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/VSCodium/vscodium/releases/download/${version}/VSCodium-${plat}-${version}.${archive_fmt}";
|
|
inherit sha256;
|
|
};
|
|
|
|
tests = nixosTests.vscodium;
|
|
|
|
updateScript = ./update-vscodium.sh;
|
|
|
|
meta = with lib; {
|
|
description = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS (VS Code without MS branding/telemetry/licensing)
|
|
'';
|
|
longDescription = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS. It includes support for debugging, embedded Git
|
|
control, syntax highlighting, intelligent code completion, snippets,
|
|
and code refactoring. It is also customizable, so users can change the
|
|
editor's theme, keyboard shortcuts, and preferences
|
|
'';
|
|
homepage = "https://github.com/VSCodium/vscodium";
|
|
downloadPage = "https://github.com/VSCodium/vscodium/releases";
|
|
license = licenses.mit;
|
|
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
|
|
maintainers = with maintainers; [ synthetica turion bobby285271 ];
|
|
mainProgram = "codium";
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" "armv7l-linux" ];
|
|
};
|
|
}
|