Luke Granger-Brown
6266b42b66
This is a helper utility for syncing filesystem files into GitLab variables, for deploy-time secrets.
39 lines
1.1 KiB
Nix
39 lines
1.1 KiB
Nix
{ pkgs, lib, depot, ... }:
|
|
let
|
|
secretsync = pkgs.buildGoModule rec {
|
|
pname = "secretsync";
|
|
version = "0.0.1";
|
|
|
|
src = ./.;
|
|
modSha256 = "17m97rfxwbq7vvggvjkxrzakvlk83n0caciv80d50hgdljs3ks0m";
|
|
|
|
subPackages = [ "." ];
|
|
|
|
meta = with lib; {
|
|
description = "Simple package for dumping secret files from disk to GitLab variables";
|
|
};
|
|
};
|
|
in secretsync // {
|
|
configure = baseConfig:
|
|
let
|
|
config = {
|
|
name = "secretsync";
|
|
pkg = secretsync;
|
|
gitlabAccessToken = "";
|
|
gitlabEndpoint = "https://hg.lukegb.com";
|
|
gitlabProject = "lukegb/depot";
|
|
variablesToFile = {};
|
|
logToStderr = true;
|
|
} // baseConfig;
|
|
args = {
|
|
gitlab_access_token = config.gitlabAccessToken;
|
|
gitlab_endpoint = config.gitlabEndpoint;
|
|
gitlab_project = config.gitlabProject;
|
|
variable_to_file = lib.mapAttrsToList (name: value: "${name}=${value}") config.variablesToFile;
|
|
logtostderr = config.logToStderr;
|
|
};
|
|
in
|
|
pkgs.writeShellScriptBin config.name ''
|
|
exec "${config.pkg}/bin/secretsync" ${lib.cli.toGNUCommandLineShell {} args}
|
|
'';
|
|
}
|