57 lines
1.7 KiB
Nix
57 lines
1.7 KiB
Nix
{ lib, stdenv, fetchurl, unzip, makeWrapper, gawk, glibc }:
|
|
|
|
let
|
|
version = "1.7.3";
|
|
|
|
sources = let
|
|
base = "https://releases.hashicorp.com/vault/${version}";
|
|
in {
|
|
x86_64-linux = fetchurl {
|
|
url = "${base}/vault_${version}_linux_amd64.zip";
|
|
sha256 = "sha256-hFMTKpO3VcCondSy8amb1K8G+BZ7gZF/EXCAg5Ax4D8=";
|
|
};
|
|
i686-linux = fetchurl {
|
|
url = "${base}/vault_${version}_linux_386.zip";
|
|
sha256 = "02wbbzffb2m7y3476l5qa5dhi0v30f3sfif0svqhhzh927kg4s5w";
|
|
};
|
|
x86_64-darwin = fetchurl {
|
|
url = "${base}/vault_${version}_darwin_amd64.zip";
|
|
sha256 = "0sw56dhjbasdnlwg668swhyxrn5gy7h9gysdg96za4dhq3iimkrn";
|
|
};
|
|
aarch64-linux = fetchurl {
|
|
url = "${base}/vault_${version}_linux_arm64.zip";
|
|
sha256 = "0c2w0684adaqildwviajp6pi8vp76g4zwwgc1k2bb5mwv1h2y293";
|
|
};
|
|
};
|
|
|
|
in stdenv.mkDerivation {
|
|
pname = "vault-bin";
|
|
inherit version;
|
|
|
|
src = sources.${stdenv.hostPlatform.system} or (throw "unsupported system: ${stdenv.hostPlatform.system}");
|
|
|
|
nativeBuildInputs = [ makeWrapper unzip ];
|
|
|
|
sourceRoot = ".";
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin $out/share/bash-completion/completions
|
|
mv vault $out/bin
|
|
echo "complete -C $out/bin/vault vault" > $out/share/bash-completion/completions/vault
|
|
|
|
wrapProgram $out/bin/vault \
|
|
--prefix PATH ${lib.makeBinPath [ gawk glibc ]}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.vaultproject.io";
|
|
description = "A tool for managing secrets, this binary includes the UI";
|
|
platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" "aarch64-linux" ];
|
|
license = licenses.mpl20;
|
|
maintainers = with maintainers; teams.serokell.members ++ [ offline psyanticy Chili-Man ];
|
|
};
|
|
}
|