79 lines
2.6 KiB
Nix
79 lines
2.6 KiB
Nix
{ lib, stdenv, appimageTools, fetchurl, makeWrapper, _7zz }:
|
|
|
|
let
|
|
pname = "joplin-desktop";
|
|
version = "3.0.15";
|
|
|
|
inherit (stdenv.hostPlatform) system;
|
|
throwSystem = throw "Unsupported system: ${system}";
|
|
|
|
suffix = {
|
|
x86_64-linux = ".AppImage";
|
|
x86_64-darwin = ".dmg";
|
|
aarch64-darwin = "-arm64.dmg";
|
|
}.${system} or throwSystem;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/laurent22/joplin/releases/download/v${version}/Joplin-${version}${suffix}";
|
|
sha256 = {
|
|
x86_64-linux = "sha256-rNKYihIbdfGZEIGURyty+hS82ftHsqV1YjqM8VYB6RU=";
|
|
x86_64-darwin = "sha256-s7gZSr/5VOg8bqxGPckK7UxDpvmsNgdhjDg+lxnO/lU=";
|
|
aarch64-darwin = "sha256-UzAGYIKd5swtl6XNFVTPeg0nqwKKtu0e36+LA0Qiusw=";
|
|
}.${system} or throwSystem;
|
|
};
|
|
|
|
appimageContents = appimageTools.extractType2 {
|
|
inherit pname version src;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Open source note taking and to-do application with synchronisation capabilities";
|
|
mainProgram = "joplin-desktop";
|
|
longDescription = ''
|
|
Joplin is a free, open source note taking and to-do application, which can
|
|
handle a large number of notes organised into notebooks. The notes are
|
|
searchable, can be copied, tagged and modified either from the
|
|
applications directly or from your own text editor. The notes are in
|
|
Markdown format.
|
|
'';
|
|
homepage = "https://joplinapp.org";
|
|
license = licenses.agpl3Plus;
|
|
maintainers = with maintainers; [ hugoreeves qjoly ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-darwin" ];
|
|
};
|
|
|
|
linux = appimageTools.wrapType2 rec {
|
|
inherit pname version src meta;
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
profile = ''
|
|
export LC_ALL=C.UTF-8
|
|
'';
|
|
|
|
extraInstallCommands = ''
|
|
wrapProgram $out/bin/${pname} \
|
|
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform=wayland --enable-features=WaylandWindowDecorations}}"
|
|
install -Dm444 ${appimageContents}/@joplinapp-desktop.desktop -t $out/share/applications
|
|
install -Dm444 ${appimageContents}/@joplinapp-desktop.png -t $out/share/pixmaps
|
|
substituteInPlace $out/share/applications/@joplinapp-desktop.desktop \
|
|
--replace 'Exec=AppRun' 'Exec=${pname}' \
|
|
--replace 'Icon=joplin' "Icon=@joplinapp-desktop"
|
|
'';
|
|
};
|
|
|
|
darwin = stdenv.mkDerivation {
|
|
inherit pname version src meta;
|
|
|
|
nativeBuildInputs = [ _7zz ];
|
|
|
|
sourceRoot = "Joplin.app";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/Applications/Joplin.app
|
|
cp -R . $out/Applications/Joplin.app
|
|
'';
|
|
};
|
|
in
|
|
if stdenv.hostPlatform.isDarwin
|
|
then darwin
|
|
else linux
|