77 lines
2.4 KiB
Nix
77 lines
2.4 KiB
Nix
{ stdenv, appimageTools, fetchurl, gsettings-desktop-schemas, gtk3, undmg }:
|
|
|
|
let
|
|
pname = "joplin-desktop";
|
|
version = "1.3.18";
|
|
name = "${pname}-${version}";
|
|
|
|
inherit (stdenv.hostPlatform) system;
|
|
throwSystem = throw "Unsupported system: ${system}";
|
|
|
|
suffix = {
|
|
x86_64-linux = "AppImage";
|
|
x86_64-darwin = "dmg";
|
|
}.${system} or throwSystem;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/laurent22/joplin/releases/download/v${version}/Joplin-${version}.${suffix}";
|
|
sha256 = {
|
|
x86_64-linux = "1dldy137ia8qxhf7d5xzq5slm12bhnmw4kx7fm37n1ajjdcn5sf7";
|
|
x86_64-darwin = "0zm9vhxlfs1ldd8za4yha54psqwl0al4hzdfxjfp7ir98i9a4cj7";
|
|
}.${system} or throwSystem;
|
|
};
|
|
|
|
appimageContents = appimageTools.extractType2 {
|
|
inherit name src;
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "An open source note taking and to-do application with synchronisation capabilities";
|
|
longDescription = ''
|
|
Joplin is a free, open source note taking and to-do application, which can
|
|
handle a large number of notes organised into notebooks. The notes are
|
|
searchable, can be copied, tagged and modified either from the
|
|
applications directly or from your own text editor. The notes are in
|
|
Markdown format.
|
|
'';
|
|
homepage = "https://joplinapp.org";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ hugoreeves ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" ];
|
|
};
|
|
|
|
linux = appimageTools.wrapType2 rec {
|
|
inherit name src meta;
|
|
|
|
profile = ''
|
|
export LC_ALL=C.UTF-8
|
|
export XDG_DATA_DIRS=${gsettings-desktop-schemas}/share/gsettings-schemas/${gsettings-desktop-schemas.name}:${gtk3}/share/gsettings-schemas/${gtk3.name}:$XDG_DATA_DIRS
|
|
'';
|
|
|
|
multiPkgs = null; # no 32bit needed
|
|
extraPkgs = appimageTools.defaultFhsEnvArgs.multiPkgs;
|
|
extraInstallCommands = ''
|
|
mv $out/bin/{${name},${pname}}
|
|
install -Dm444 ${appimageContents}/joplin.desktop -t $out/share/applications
|
|
install -Dm444 ${appimageContents}/joplin.png -t $out/share/pixmaps
|
|
substituteInPlace $out/share/applications/joplin.desktop \
|
|
--replace 'Exec=AppRun' 'Exec=${pname}'
|
|
'';
|
|
};
|
|
|
|
darwin = stdenv.mkDerivation {
|
|
inherit name src meta;
|
|
|
|
nativeBuildInputs = [ undmg ];
|
|
|
|
sourceRoot = "Joplin.app";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/Applications/Joplin.app
|
|
cp -R . $out/Applications/Joplin.app
|
|
'';
|
|
};
|
|
in
|
|
if stdenv.isDarwin
|
|
then darwin
|
|
else linux
|