75 lines
1.8 KiB
Nix
75 lines
1.8 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, symlinkJoin }:
|
|
|
|
let
|
|
version = "3.5.9";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "etcd-io";
|
|
repo = "etcd";
|
|
rev = "v${version}";
|
|
hash = "sha256-Vp8U49fp0FowIuSSvbrMWjAKG2oDO1o0qO4izSnTR3U=";
|
|
};
|
|
|
|
CGO_ENABLED = 0;
|
|
|
|
meta = with lib; {
|
|
description = "Distributed reliable key-value store for the most critical data of a distributed system";
|
|
license = licenses.asl20;
|
|
homepage = "https://etcd.io/";
|
|
maintainers = with maintainers; [ offline zowoq endocrimes ];
|
|
platforms = platforms.darwin ++ platforms.linux;
|
|
};
|
|
|
|
etcdserver = buildGoModule rec {
|
|
pname = "etcdserver";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = "sha256-vu5VKHnDbvxSd8qpIFy0bA88IIXLaQ5S8dVUJEwnKJA=";
|
|
|
|
modRoot = "./server";
|
|
|
|
preInstall = ''
|
|
mv $GOPATH/bin/{server,etcd}
|
|
'';
|
|
|
|
# We set the GitSHA to `GitNotFound` to match official build scripts when
|
|
# git is unavailable. This is to avoid doing a full Git Checkout of etcd.
|
|
# User facing version numbers are still available in the binary, just not
|
|
# the sha it was built from.
|
|
ldflags = [ "-X go.etcd.io/etcd/api/v3/version.GitSHA=GitNotFound" ];
|
|
};
|
|
|
|
etcdutl = buildGoModule rec {
|
|
pname = "etcdutl";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = "sha256-i60rKCmbEXkdFOZk2dTbG5EtYKb5eCBSyMcsTtnvATs=";
|
|
|
|
modRoot = "./etcdutl";
|
|
};
|
|
|
|
etcdctl = buildGoModule rec {
|
|
pname = "etcdctl";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = "sha256-awl/4kuOjspMVEwfANWK0oi3RId6ERsFkdluiRaaXlA=";
|
|
|
|
modRoot = "./etcdctl";
|
|
};
|
|
in
|
|
symlinkJoin {
|
|
name = "etcd-${version}";
|
|
|
|
inherit meta version;
|
|
|
|
passthru = { inherit etcdserver etcdutl etcdctl; };
|
|
|
|
paths = [
|
|
etcdserver
|
|
etcdutl
|
|
etcdctl
|
|
];
|
|
}
|