Luke Granger-Brown
57725ef3ec
git-subtree-dir: third_party/nixpkgs git-subtree-split: 76612b17c0ce71689921ca12d9ffdc9c23ce40b2
42 lines
1.3 KiB
Nix
42 lines
1.3 KiB
Nix
{ stdenv, lib, kernel, rr }:
|
|
|
|
/* The python script shouldn't be needed for users of this kernel module.
|
|
https://github.com/rr-debugger/rr/blob/master/scripts/zen_workaround.py
|
|
The module itself is called "zen_workaround" (a bit generic unfortunately).
|
|
*/
|
|
stdenv.mkDerivation {
|
|
pname = "rr-zen_workaround";
|
|
|
|
inherit (rr) src version;
|
|
sourceRoot = "source/third-party/zen-pmu-workaround";
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
nativeBuildInputs = kernel.moduleBuildDependencies;
|
|
|
|
makeFlags = [
|
|
"-C${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
];
|
|
postConfigure = ''
|
|
makeFlags="$makeFlags M=$(pwd)"
|
|
'';
|
|
buildFlags = [ "modules" ];
|
|
|
|
installPhase = let
|
|
modDestDir = "$out/lib/modules/${kernel.modDirVersion}/kernel"; #TODO: longer path?
|
|
in ''
|
|
runHook preInstall
|
|
mkdir -p "${modDestDir}"
|
|
cp *.ko "${modDestDir}/"
|
|
find ${modDestDir} -name '*.ko' -exec xz -f '{}' \;
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Kernel module supporting the rr debugger on (some) AMD Zen-based CPUs";
|
|
homepage = "https://github.com/rr-debugger/rr/wiki/Zen#kernel-module";
|
|
license = licenses.gpl2;
|
|
maintainers = [ maintainers.vcunat ];
|
|
platforms = [ "x86_64-linux" ];
|
|
broken = versionOlder kernel.version "4.19"; # 4.14 breaks and 4.19 works
|
|
};
|
|
}
|