68 lines
2.2 KiB
Nix
68 lines
2.2 KiB
Nix
{ lib, stdenv, callPackage, fetchurl, nixosTests }:
|
|
|
|
let
|
|
inherit (stdenv.hostPlatform) system;
|
|
|
|
plat = {
|
|
x86_64-linux = "linux-x64";
|
|
x86_64-darwin = "darwin-x64";
|
|
aarch64-linux = "linux-arm64";
|
|
armv7l-linux = "linux-armhf";
|
|
}.${system};
|
|
|
|
archive_fmt = if system == "x86_64-darwin" then "zip" else "tar.gz";
|
|
|
|
sha256 = {
|
|
x86_64-linux = "0yx0h7rd8v9j3yq863dj78bm587s8lpisbn1skb5whv6qv88x7c0";
|
|
x86_64-darwin = "1b5jr08cgl49rh26id8iwi64d32ssr7kis72zcqg0jkw7larxvvh";
|
|
aarch64-linux = "1a62krnilfi7nr7mmxyv3danj7h2yfdwg784q8vhrdjyqjd8gjbs";
|
|
armv7l-linux = "1axazx7hf6iw0dq1m2049kfrmk8jndycz9pcn3csj6rm65plg746";
|
|
}.${system};
|
|
|
|
sourceRoot = {
|
|
x86_64-linux = ".";
|
|
x86_64-darwin = "";
|
|
aarch64-linux = ".";
|
|
armv7l-linux = ".";
|
|
}.${system};
|
|
in
|
|
callPackage ./generic.nix rec {
|
|
inherit sourceRoot;
|
|
|
|
# Please backport all compatible updates to the stable release.
|
|
# This is important for the extension ecosystem.
|
|
version = "1.59.0";
|
|
pname = "vscodium";
|
|
|
|
executableName = "codium";
|
|
longName = "VSCodium";
|
|
shortName = "vscodium";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/VSCodium/vscodium/releases/download/${version}/VSCodium-${plat}-${version}.${archive_fmt}";
|
|
inherit sha256;
|
|
};
|
|
|
|
tests = nixosTests.vscodium;
|
|
|
|
updateScript = ./update-vscodium.sh;
|
|
|
|
meta = with lib; {
|
|
description = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS (VS Code without MS branding/telemetry/licensing)
|
|
'';
|
|
longDescription = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS. It includes support for debugging, embedded Git
|
|
control, syntax highlighting, intelligent code completion, snippets,
|
|
and code refactoring. It is also customizable, so users can change the
|
|
editor's theme, keyboard shortcuts, and preferences
|
|
'';
|
|
homepage = "https://github.com/VSCodium/vscodium";
|
|
downloadPage = "https://github.com/VSCodium/vscodium/releases";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ synthetica turion ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "armv7l-linux" ];
|
|
};
|
|
}
|