46 lines
1.3 KiB
Nix
46 lines
1.3 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, makeWrapper, iptables, iproute }:
|
|
|
|
buildGoModule rec {
|
|
pname = "tailscale";
|
|
version = "1.4.4";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "tailscale";
|
|
repo = "tailscale";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-zrKkBbsvIqJkPysKx3nJ3EIbePWMZCX9eegekAoqMqk=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
CGO_ENABLED = 0;
|
|
|
|
vendorSha256 = "sha256-WvojOnGQ/ssBkoQwIlOVsaEUJmi2ugqgtTAVKJg8Spk=";
|
|
|
|
doCheck = false;
|
|
|
|
subPackages = [ "cmd/tailscale" "cmd/tailscaled" ];
|
|
|
|
preBuild = ''
|
|
export buildFlagsArray=(
|
|
-tags="xversion"
|
|
-ldflags="-X tailscale.com/version.Long=${version} -X tailscale.com/version.Short=${version}"
|
|
)
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/tailscaled --prefix PATH : ${
|
|
lib.makeBinPath [ iproute iptables ]
|
|
}
|
|
sed -i -e "s#/usr/sbin#$out/bin#" -e "/^EnvironmentFile/d" ./cmd/tailscaled/tailscaled.service
|
|
install -D -m0444 -t $out/lib/systemd/system ./cmd/tailscaled/tailscaled.service
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://tailscale.com";
|
|
description = "The node agent for Tailscale, a mesh VPN built on WireGuard";
|
|
platforms = platforms.linux;
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ danderson mbaillie ];
|
|
};
|
|
}
|